[AS3] Array에 추가된 새로운 메소드들

every() 메소드    
AS3 function every(callback:Function, thisObject:* = null):Boolean

지정된 함수에서 false를 돌려주는 아이템에 이를 때까지 배열내의 각 아이템에 테스트 함수를 실행한다. 이 메소드를 사용하면 배열내의 모든 아이템이 있는 기준(값이 특정의 수치보다 작은 등)이 만족하는지 어떤지를 판별할 수 있다.

파라미터
    callback:Function — 배열내의 각 아이템에 대해 실행하는 함수. 이 함수에는 단순한 비교 (item < 20 등)나 보다 복잡한 연산을 포함할 수 있다 .또 이 함수를 호출하려면 다음과 같이 아이템의 값, 아이템의 인덱스, 및 Array 오브젝트의 3개 인수를 사용한다.

function callback(item:*, index:int, array:Array):Boolean;

    thisObject:* (default = null) — 함수의 this로서 사용하는 오브젝트.

반환값
    Boolean — 불리언 값. true를 돌려준다 (지정된 함수에 대해 배열 내의 모든 아이템이 true 를 돌려주는 경우)  그 이외의 경우는 false를 돌려준다.

다음의 예에서는 2개의 배열을 테스트하고 각 배열내의 모든 아이템이 수치인지를 판별하고 테스트 결과를 출력한다. 첫번째 배열의 결과는 true, 2번째의 배열은 false를 나타내고 있으며 false를 받는 즉시 테스트 함수의 순회는 종료된다.

package {
        import flash.display.Sprite;
        public class Array_every extends Sprite {
                public function Array_every() {
                        var arr1:Array = new Array(1, 2, 4);
                        var res1:Boolean = arr1.every(isNumeric);
                        trace("isNumeric:", res1);// true

                        var arr2:Array = new Array(1, "ham", 2);
                        var res2:Boolean = arr2.every(isNumeric);
                        trace("isNumeric:", res2);// false
                }
                private function isNumeric(element:*, index:int, arr:Array):Boolean {
                        trace(element);
                        return (element is Number);
                }
        }
}

출력 :
1
2
4
isNumeric: true
1
ham
isNumeric: false


forEach( ) 메소드    
AS3 function forEach(callback:Function, thisObject:* = null):void

배열내의 각 아이템에 대해 함수를 실행한다.

파라미터
    callback:Function — 배열내의 각 아이템에 대해 실행하는 함수. 이 함수에는 단순한 커멘드 (trace() 스테이트먼트 등)나 보다 복잡한 연산을 포함할 수 있다. 또 이 함수를 호출하려면  다음과 같이 아이템의 값, 아이템의 인덱스, 및 Array 오브젝트와 같이 3개의 인수를 사용한다.

    function callback(item:*, index:int, array:Array):void;

    thisObject:* (default = null) — 함수의 this로서 사용하는 오브젝트.

다음의 예에서는 배열내의 각 아이템에 대해서 trace() 스테이트먼트를 traceEmployee() 함수로 대체하고 있다.

package {
        import flash.display.Sprite;
        public class Array_forEach extends Sprite {
                public function Array_forEach() {
                        var employees:Array = new Array();
                        employees.push({name:"Employee 1", manager:false});
                        employees.push({name:"Employee 2", manager:true});
                        employees.push({name:"Employee 3", manager:false});
                        trace(employees);
                        employees.forEach(traceEmployee);
                }
                private function traceEmployee(element:*, index:int, arr:Array):void {
                        trace(element.name + " (" + element.manager + ")");
                }
        }
}

다음의 예도 배열내의 각 아이템에 대해 trace() 스테이트먼트를 실행하고 있지만 여기서 사용한 traceEmployee() 함수에는 약간의 변경이 있다.

package {
        import flash.display.Sprite;
        public class Array_forEach_2 extends Sprite {
                public function Array_forEach_2() {
                        var employeeXML:XML = <employees>
                        <employee name="Steven" manager="false" />
                        <employee name="Bruce" manager="true" />
                        <employee name="Rob" manager="false" />
                        </employees>;
                        var employeesList:XMLList = employeeXML.employee;
                        var employeesArray:Array = new Array();
                        for each (var tempXML:XML in employeesList) {
                                employeesArray.push(tempXML);
                        }
                        employeesArray.sortOn("@name");
                        employeesArray.forEach(traceEmployee);
                }
                private function traceEmployee(element:*, index:Number, arr:Array):void {
                        trace(element.@name + ((element.@manager == "true") ? " (manager)" : ""));
                }
        }
}

filter() 메소드    
AS3 function filter(callback:Function, thisObject:* = null):Array

배열내의 각 아이템에 대해 테스트 함수를 실행하여 지정된 함수에 대해서 true를 돌려주는 모든 아이템을 포함하는 새로운 배열을 작성한다. false를 돌려주는 아이템은 새로운 배열에 포함하지 않는다.

파라미터
    callback:Function — 배열내의 각 아이템에 대해 실행하는 함수. 이 함수에는 단순한 비교 (item < 20 등)나 보다 복잡한 연산을 포함할 수 있다. 또 이 함수를 호출하려면 다음과 같이 아이템의 값, 아이템의 인덱스, 및 Array 오브젝트와 같이 3개의 인수를 사용한다.

    function callback(item:*, index:int, array:Array):Boolean;

    thisObject:* (default = null) — 함수의 this로서 사용하는 오브젝트.

반환값
    Array — 원본 배열내의 아이템으로 true를 돌려준 것을 모두 포함한 새로운 배열이다.

다음의 예에서는 관리자인 모든 종업원의 배열을 작성한다.

package {
        import flash.display.Sprite;
        public class Array_filter extends Sprite {
                public function Array_filter() {

                        var employees:Array = new Array();
                        employees.push({name:"Employee 1", manager:false});
                        employees.push({name:"Employee 2", manager:true});
                        employees.push({name:"Employee 3", manager:false});
                        trace("Employees:");
                        employees.forEach(traceEmployee);

                        var managers:Array = employees.filter(isManager);
                        trace("Managers:");
                        managers.forEach(traceEmployee);
                }
                private function isManager(element:*, index:int, arr:Array):Boolean {
                        return (element.manager == true);
                }
                private function traceEmployee(element:*, index:int, arr:Array):void {
                        trace("t" + element.name + ((element.manager) ? " (manager)" : ""));
                }
        }
}

map() 메소드    
AS3 function map(callback:Function, thisObject:* = null):Array

배열내의 각 아이템에 대해 함수를 실행하여 원본 배열의 각 아이템에 대한 함수의 결과에 대응하는 아이템으로부터 완성되는 새로운 배열을 작성한다.

파라미터
    callback:Function — 배열내의 각 아이템에 대해 실행하는 함수. 이 함수에는 단순한 커멘드 (스트링의 배열의 대문자 소문자의 변경 등)나 보다 복잡한 연산을 포함할 수 있다. 또 이 함수를 호출하려면 다음과 같이 아이템의 값, 아이템의 인덱스, 및 Array 오브젝트와 같이 3개의 인수를 사용한다.

    function callback(item:*, index:int, array:Array):void;
 
    thisObject:* (default = null) — 함수의 this로서 사용하는 오브젝트.

반환값
    Array — 원본배열내의 각 아이템의 함수의 결과가 포함되는 새로운 배열이다.

다음의 예에서는 배열내의 모든 아이템을 대문자로 변경하고 있다.

package {
        import flash.display.Sprite;
        public class Array_map extends Sprite {
                public function Array_map() {
                        var arr:Array = new Array("one", "two", "Three");
                        trace(arr); // one,two,Three

                        var upperArr:Array = arr.map(toUpper);
                        trace(upperArr); // ONE,TWO,THREE
                }
                private function toUpper(element:*, index:int, arr:Array):String {
                        return String(element).toUpperCase();
                }
        }
}

some() 메소드    
AS3 function some(callback:Function, thisObject:* = null):Boolean

true를 돌려주는 아이템에 이를 때까지 배열내의 각 아이템에 테스트 함수를 실행한다. 이 메소드를 사용하면 배열내의 어느 아이템의 기준(값이 특정의 수치보다 작은지 등)을 만족하는지 어떤지를 판별할 수 있다.

파라미터
    callback:Function — 배열내의 각 아이템에 대해 실행하는 함수. 이 함수에는 단순한 비교 (item < 20 등)나 보다 복잡한 연산을 포함할 수 있다. 또 이 함수를 호출하려면 다음과 같이 아이템의 값, 아이템의 인덱스, 및 Array 오브젝트와 같이 3개의 인수를 사용한다.

    function callback(item:*, index:int, array:Array):Boolean;

    thisObject:* (default = null) — 함수의 this로서 사용하는 오브젝트.

반환값
    Boolean — 불리언 값. true를 돌려준다. (지정된 함수에 대해 배열내의 몇개의 아이템이 true를 돌려주는 경우). 그 이외의 경우는 false를 돌려준다.

다음의 예에서는 배열 내 요소 중 undefined 값이 포함된 것을 표시한다.

package {
        import flash.display.Sprite;
        public class Array_some extends Sprite {
                public function Array_some() {
                        var arr:Array = new Array();
                        arr[0] = "one";
                        arr[1] = "two";
                        arr[3] = "four";
                        var isUndef:Boolean = arr.some(isUndefined);
                        trace(isUndef);
                        if (isUndef) {
                                trace("array contains undefined values: " + arr);
                        } else {
                                trace("array contains no undefined values.");
                        }
                }
                private function isUndefined(element:*, index:int, arr:Array):Boolean {
                        return (element == undefined);
                }
        }
}

출력 :
true
array contains undefined values: one,two,,four