jasu's blog

1. 복수의 변수의 출력이 편하게：trace
인수에 변수를 복수 건네주면 자동적으로 공백으로 구분하여 출력한다. 3.0 이전에도 굳이 필요하다면 trace([a,b])와 같은 방법으로 사용하였었는데 뭐 자체 지원이니…

var a:int = 0;
var b:String = 'hgoe';
trace(a, b); // Output: 0 hoge

2. 요소의 순회가 간단히：for each
이전에는 배열의 요소를 순회하는 것은 다음과 같이 하는 것이 정석이었다.

var len:Number = list.length;
for (var i:Number = 0; i < len; ++i) {
        trace(list[i]);
}

하지만 3.0에서는 다음과 같이 사용하면 이런 귀찮은 일이 많이 줄어든다. list 안의 요소가 하나씩 element에 대입되어 loop된다.

for each (var element:Object in list) {
        trace(element);
}

3. 솔직하게 쓸 수 있게 되었다：default 인수
다음과 같이 인수를 생략 했을 경우의 default값을 간단하게 지정할 수 있다.

function f(arg1:int, arg2:int = 2):void
{
        trace(arg1, arg2);
}
f(3, 4); // Output: 3 4
f(3); // Output: 3 2

4. arguments는 필요없다：가변 인수
trace와 같이 얼마든지 인수를 잡는 함수에서는 다음과 같이 쓸 수 있다. 지정한 인수(여기에서는rest )에 나머지의 인수를 배열로서 받을 수가 있다.

function output(separator:String, ...rest:Array):void
{
        trace(rest.join(separator));
}
output(':', 1, 2, 3, 4); // Output: 1:2:3:4
output('.', 'a', 'b', 'c'); // Output: a.b.c

5. 모든 형태를 나타낸다：*
어떤 형태가 대입되는지 모르지만 형태를 지정하고 싶을 경우 기존에는 Object가 이용되고 있었지만 AS3에서는 보다 그 의미를 명확하게 하기 위해서, 「* 」(asterisk)라고 하는 형태 지정을 할 수 있다.

var element:* = list[0];

6. 변경되지 않는 상수：const
한 번 값을 설정하면 실행 중에는 변경할 수 없는 이른바 「상수」를 정의할 수 있다.

public class SelectedEvent extends Event
{
        public static const SELECTED:String = 'selected';
}

7. 복수의 루프를 단번에 빠진다：label
다중 루프를 단번에 break 하거나 continue 하거나 할 수가 있게 되었다. switch case 에서 친숙한 라벨을 쓰고 break나 continue를 할 때에 그것을 지정하면 그 라벨에 대해서 동작을 한다.

loop: for (var i:int = 0; i < 2; i++) {
        for (var j:int = 0; j < 3; j++) {
                if ((i == 1) && (j == 0)) {
                        break loop;
                }
                trace(i, j);
        }
}
/* Output:
0 0
0 1
0 2
*/

설명：「loop 」라는 라벨을 지정하고 그 안에 상자가 된 루프가 있다. 루프는 최초로 i=0 으로부터 1씩 증가하며 한번 증가할 때마다 j루프를 돌게 되는데 if문을 만나는 순간, break에 의해서loop 라벨로부터 탈출(?!)하여 두 루프를 빠져 버리므로 Output과 같은 결과가 된다. 보통 이러한 형태는 인터프리터언어(순차적 언어)에서 주로 사용되었던 방식이었는데 그 복잡한 흐름 때문에 순차적 언어에서도 꺼려하는 방법이었다. 하지만 간단한 내부 알고리즘에서 활용하면 편할 것 같기는 하다.


8. 프롭퍼티의 존재를 간단하게 확인：in
「a in b 」와 같이 쓰면 b의 안에 프롭퍼티 a가 들어가 있으면 true, 그렇지 않으면 false 반환한다.이것에 이용하면 프롭퍼티 존재를 간단하게 조사할 수가 있다.

var obj:Object = {abc: 1, def: 2};
trace('abc' in obj); // Output: true
trace('ghi' in obj); // Output: false

9. 오브젝트가 특정의 형태인가 간단하게 확인：is
「a is b 」와 같이 쓰면 a가 b와 형태가 같거나 b의 서브 클래스의 인스턴스이면 true, 그렇지 않으면 false를 반환한다. 이것에 이용하면 어느 형태인가를 간단하게 조사할 수가 있다.

var s:Sprite = new Sprite();
trace(s is Sprite); // Output: true
trace(s is DisplayObject); // Output: true
trace(s is String); // Output: false

*instanceof 는 직접적인 인스턴스가 아니면 true를 반환하지 않기 때문에 주의해야 한다.

var s:Sprite = new Sprite();
trace(s instanceof Sprite); // Output: true
trace(s instanceof DisplayObject); // Output: false

10. 예외 없이 캐스트：as
보통 다음과 같이 캐스트 하려고 했을 때 형태가 맞지 않으면 예외가 슬로우 된다.

var s:Sprite = Sprite(new Array());

그러나 as를 사용해 캐스트 하면 형태가 맞지 않는 경우, 예외는 슬로우 되지 않고 그 형태의 디폴트값을 돌려준다.

var s:Sprite = new Array() as Sprite;
trace(s);  // Output: null ← 형태 지정으로 null을 반환한다.
var n:Number = new Array() as Number;
trace(n);  // Output: 0 ← Number의 디폴트값은 0

WheelParticle 클래스를 상속하여 Square 클래스를 만들어 봤다. WheelParticle 클래스에서는 angle 메소드를 원하고 있어서 paint 메소드를 오버라이드 할때 그리게 되는 graphics의 rotation에 적용하였다.

화면에서 마우스를 클릭하고 있으면 Square 오브젝트 들이 생성하며 일정한 범위(y값 450) 이상으로 넘어가는 오브젝트는 엔진에서 제외(and sprite 삭제) 하였다.

엔 진에서 제외할 때 더이상 사용하지 않는 sprite인 경우에는 delete 시켜줄 필요가 있다. removeParticle을 실행할 때 cleanup 메소드를 통해서 해당 sprite에 있는 오브젝트들을 removeChildAt 시켜주지만 sprite 그 자체는 메모리에 남아있게 된다.

왼쪽, 오른쪽에는 경계영역을 만들어 분산되는 오브젝트들을 어느정도 밀집시켰다.

APE UML 자료를 찾아보려고 하였으나 공개된 UML자료가 없어서 클래스를 토대로 임의로 만들어 놓았다. 위 이미지는 APE의 클래스 명으로 표기한 기본적인 class diagram이다. 아직 APE의 클래스 관계가 제대로 파악되지 않아서 generalization과 realization  관계만을 표시해 놓았다. 위 이미지는  클래스명으로만 간략하게 표시해 놓았지만 아래 파일은  각 클래스에 있는 attribute와 operation도 포함해 놓았으니 ape를 분석하시는 분에게는 도움이 될 듯 싶다. exe파일로 퍼블리시 해 놓았는데 예전에 AS3 API 계층 구조도를 만들 때 사용했던 소스를 그대로 사용하였다.

가끔 닉네임이 왜 자수(jasu)인지 물어보시는 분들이 있다. 사전을 찾아보면 여러가지 뜻을 볼 수 있는데 사전에서의 자수라는 단어의 뜻은 상당히 상반된 뜻을 지니고 있다.

사실 자수라는 닉네임은 예전에 PC통신 시절 천리안의 모 클럽의 익명 게시판에서 활동을 할 당시에 처음 사용하게 되었는데 작명을 할 때는 다음과 같은 뜻을 생각해서 지은 것이 아니라 그냥 단어의 뉘앙스가 좋아서 사용하게 되었다.

사전에서 나쁜 뜻은 버리고 좋은 뜻으로만 모아보면 다음과 같다.

자수 [自手] : 자기 혼자의 노력이나 힘.
자수 [自守] : 행동이나 말을 스스로 조심하여 지킴.
자수 [自修] : 남의 가르침을 직접 받지 않고 자기의 힘으로 학문을 닦음.